home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib15.dsk / DISKETTE ENVELOPER.bas < prev    next >
BASIC Source File  |  2023-02-26  |  3KB  |  63 lines
  1. 1  REM  **********************
  2. 2  REM  * DISKETTE ENVELOPER *
  3. 3  REM  *  BY DAVID POWELL   *
  4. 4  REM  * COPYRIGHT (C) 1982 *
  5. 5  REM  * BY MICRO-SPARC INC *
  6. 6  REM  * LINCOLN, MA. 01773 *
  7. 7  REM  **********************
  8. 50  TEXT : HOME 
  9. 60  VTAB 3: HTAB 5: FOR I = 1 TO 32: PRINT  CHR$(95);: NEXT : PRINT 
  10. 70  PRINT  TAB( 5)"!"; TAB( 36);"!": PRINT  TAB( 5)"!"; TAB( 36);"!"
  11. 80  VTAB 6: HTAB 5: PRINT "!  DAVID'S DISKETTE ENVELOPER  !": PRINT  TAB( 5);"!"; TAB( 36);"!"
  12. 90  FOR I = 1 TO 40: PRINT "-";: NEXT 
  13. 100  FOR I = 1 TO 3: PRINT "!"; TAB( 40);"!";: NEXT 
  14. 110  VTAB 12: PRINT "! IT'S EASY! JUST SET UP YOUR PRINTER, !!  PUT A DISKETTE IN YOUR DISK DRIVE   !!  AND PRESS RETURN.                   !";
  15. 120  FOR I = 1 TO 4: PRINT "!"; TAB( 40);"!";: NEXT I
  16. 130  POKE 1920,171: POKE 1959,171: POKE 1924,186: POKE 1955,186: POKE 1360,171: POKE 1399,171
  17. 140  FOR I = 1 TO 20: PRINT "--";: NEXT I
  18. 150  VTAB 22: HTAB 20: GET GO$: PRINT : HTAB 20: VTAB 23
  19. 160  LOMEM: ( PEEK(106) +17) *256
  20. 170 Z =  PEEK(106) -16
  21. 180 D$ =  CHR$(4):DD$ = "-----------------------------------------------------------------------":LL$ = "!      !":LR$ = LL$
  22. 190  PRINT D$;"NOMON I,O,C"
  23. 200  FOR I = 768 TO 809: READ K: POKE I,K: NEXT I
  24. 210  POKE 6,0: POKE 7,Z
  25. 220 C =  PEEK(54) + PEEK(55) *256
  26. 230 C = C +2966
  27. 240  POKE C,0: POKE C +1,3
  28. 250  POKE C +2,39: POKE C +3,3
  29. 260  PRINT D$;"CATALOG"
  30. 270  PRINT D$;"PR#0": PRINT D$;"IN#0"
  31. 280  POKE 54,7: POKE 55,193
  32. 290 M =  PEEK(111) + PEEK(112) *256:M = M +7600
  33. 300 C = 1
  34. 310  PRINT : PRINT DD$;"  CUT": PRINT LL$; SPC( 55);LR$
  35. 320  PRINT LL$; SPC( 20);
  36. 330  FOR N = M +11 TO M  STEP  -1: PRINT  CHR$( PEEK(N) -128);: NEXT N
  37. 340  IF  PEEK(47094) <100  THEN  PRINT " ";
  38. 350  IF  PEEK(47094) <10  THEN  PRINT " ";
  39. 360  PRINT  STR$( PEEK(47094)); SPC( 20);LR$: PRINT LL$; SPC( 55);LR$
  40. 370  FOR I = Z *256 +19 TO ( PEEK(6) + PEEK(7) *256) -1  STEP 76
  41. 380 K = I +38
  42. 390  PRINT LL$"  ";
  43. 400  FOR J = I +4 TO I +28
  44. 410  PRINT  CHR$( PEEK(J));
  45. 420  NEXT J:C = C +1
  46. 430  IF K >(( PEEK(6) +256 * PEEK(7)) -1)  THEN  PRINT  SPC( 28);LR$: GOTO 510
  47. 440  PRINT "  ";
  48. 450  FOR J = K +4 TO K +28
  49. 460  PRINT  CHR$( PEEK(J));
  50. 470  NEXT J
  51. 480  PRINT " ";LR$;: PRINT 
  52. 490  IF C = 20  THEN LR$ = "!       ":LL$ = "       !": PRINT DD$;"  FOLD": PRINT LL$; SPC( 55);LR$: PRINT LL$; SPC( 55);LR$:C = C +2
  53. 500  NEXT I
  54. 510  FOR I = 1 TO 48 -C
  55. 520 C = C +1
  56. 530  IF C = 20  THEN LR$ = "!       ":LL$ = "       !": PRINT DD$;"  FOLD": PRINT LL$; SPC( 55);LR$: PRINT LL$; SPC( 55);LR$:I = I +2
  57. 540  PRINT LL$; SPC( 55);LR$: NEXT I
  58. 550  PRINT "       "; CHR$(92);"-------------------------------------------------------/  CUT": PRINT  CHR$(12)
  59. 560  PR# 0
  60. 570  HOME : VTAB 12: HTAB 6: PRINT "ENVELOPE ANOTHER DISKETTE? ";: GET Q$: PRINT 
  61. 580  IF  LEFT$(Q$,1) < >"N"  THEN 50
  62. 590  DATA  56,72,140,38,3,160,0,201,32,176,2,105,192,201,96,176,2,105,128,201,128,176,2,105,64,145,6,230,6,208,2,230,7,104,172,38,3,96,0,169,160,96
  63. 600  END